An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Chapter 3 - Puzzles

Current setting is a number that varies. The current setting is 1.

Instead of turning left the knob:
    if current setting is 1, change current setting to the number of rows in Table MM1;
    otherwise change current setting to current setting minus 1;
    choose row current setting in Table MM1;
    say "You turn the knob to the left, and the display flickers and changes to '[verbiage entry]'."

Instead of turning right the knob:
    if current setting is the number of rows in Table MM1, change current setting to 1;
    otherwise change current setting to current setting plus 1;
    choose row current setting in Table MM1;
    say "You turn the knob to the right, and the display flickers and changes to '[verbiage entry]'."

Instead of turning the knob, try turning right the knob.

Instead of examining the display:
    choose row current setting in Table MM1;
    say "The display reads '[verbiage entry]'."

Before opening the little door for the first time:
    let cnt be the number of rows in Table MM1;
    repeat with N running from 1 to cnt begin;
        choose row N in Table MM1;
        let choice-a be the fruit entry;
        let swprow be a random number from 1 to cnt;
        if swprow is not N begin;
            choose row swprow in Table MM1;
            let choice-b be the fruit entry;
            change the fruit entry to choice-a;
            choose row N in Table MM1;
            change the fruit entry to choice-b;
        end if;
    end repeat;

[There's gotta be a better way to do this; begin;]
Instead of examining the yellow card, say "Written on the yellow card is the number [yellow card desc]."
Instead of examining the orange card, say "Written on the orange card is the number [orange card desc]."
Instead of examining the green card, say "Written on the green card is the number [green card desc]."
Instead of examining the red card, say "Written on the red card is the number [red card desc]."

To say yellow card desc:
    let mycode be the code corresponding to a fruit of petrified lemon in Table MM1;
    say mycode.

To say orange card desc:
    let mycode be the code corresponding to a fruit of petrified orange in Table MM1;
    say mycode.

To say green card desc:
    let mycode be the code corresponding to a fruit of petrified grape in Table MM1;
    say mycode.

To say red card desc:
    let mycode be the code corresponding to a fruit of petrified apple in Table MM1;
    say mycode.
[end not a better way;]

Before putting something on the flat hard surface when the flat hard surface supports something:
    say "The machine only holds one thing at a time.";
    stop the action.

Instead of pushing the great huge machine, try pushing the machine button.

Before pushing the machine button when the broken machine flag is 1:
    say "Alas, the behemoth is irreparably damaged.";
    stop the action.

Instead of pushing the machine button when the flat hard surface supports something (called fitem):
    choose row current setting in Table MM1;
    if fruit entry is fitem begin;
     say "[result entry][paragraph break]";
     remove fruit entry from play;
     move a random rubbly rubble in Markm's Void to the Machine Room;
    otherwise;
     if fitem is rubbly rubble begin;
     say "Rubble is already rubble. You can't do much more to it.";
     otherwise;
     say "The giant hammer comes down in an attempt to [verbiage entry] [the fitem], but amazingly it is undamaged. Instead, the hammer breaks off into a thousand tiny shards!";
     change the broken machine flag to 1;
     remove the giant hammer from play;
     end if;
    end if;

Rubble count is a number that varies. Rubble count is 0.

Instead of inserting something (called fput) into the curious device
full of bubbly liquid:
    if fput is rubbly rubble begin;
     remove fput from play;
     change rubble count to rubble count plus 1;
     if rubble count is the number of rows in Table MM1 begin;
     move the silver key to the narrow bench;
     remove the curious device full of bubbly liquid from play;
     say "As the last bit of rubble sinks into the liquid, the device glows with an unearthly light! Brighter and brighter it gets until, at last, you have to shield your eyes. Slowly, the glow dies down and, when you look again, you see a key.";
     otherwise;
     say "The rubble sinks slowly into the liquid.";
     end if;
    otherwise;
     say "[The fput] bounces off the surface of the liquid!";
    end if;