An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Part 7 - The Chow, the whistle, and the big bird by Tom Blawgus

Section 1 - Blawgus's Part

Whisper 7 is a scene. Whisper 7 begins when Whisper 6 ends.

[LS DEBUG: Limax's original version of the following rule didn't work at all; this works but for firing before the 'you reach out and grab...' message. To actually fix this would mean adding this rule to the original 'instead', but that feels like it violates the spirit of IF Whispers--I've been fixing bugs that would be bugs in *within* a section, and bugs where things have unintended side-effects in another section, but this is pure "I want to do this." "And I want to do this." So anyway.]
Before going up from Deformed Hut when player was in the stool:
if the gaping roof flag is 1 and the player is not holding bankcheck begin;
say "The weasel grows wings and follows you!";
move the weasel to Top of the Hut;
end if;

The chow is a thing. It is in the Top of the Hut. It is a container and closed. It is openable. The printed name of the chow is "bag of weasel chow". Understand "bag", "canvas", "weasel chow", and "bag of weasel chow" as the chow. The description of the chow is "The bag reads 'Weasel Chow.' [if chow is closed]It is currently closed.[otherwise]It is open and all the food that was in it is now in the weasel's stomach.[end if][if the chow is open and number of things in the chow is greater than zero][line break]You can see [list of things in the chow] at the bottom of the bag."

Rule for writing a paragraph about chow when in Top of the Hut: say "At the corner of the roof, you spot a canvas bag."

After opening the chow for the first time: say "As you open up the bag, the weasel runs in under your arms and devours all the food in sight! He must have been pretty hungry.[line break]You see something glinting in the light at the bottom of the bag.[line break]"

A whistle is a thing. It is in the chow. Understand "glinting" and "roc whistle" as the whistle. The description of the whistle is "It's a whistle about six inches in length and as thick as your finger. It appears to be made of silver, and there's writing on it."
Instead of reading the whistle: say "The whistle reads, 'Roc Whistle.'".
Instead of blowing the whistle: say "[line break]You blow a long, loud note on the whistle. From beyond the forest, a giant bird flies overhead and grabs you in its talons and takes you with it across the trees. In alarm, you drop the whistle and watch it fade from view.[line break]Not to be left behind, the weasel again sprouts wings and follows you.[line break]";
Move the player to the Copse.;
Remove the whistle from play.

The Copse is a room. "Trees of all sizes surround you, as if in a giant chess match. Between the pawn and queen, you can see a path leading southeast, and you can make out another one to the southwest between the bishop and knight."

The pawn is scenery in the Copse. "It is a small, squat tree with broad leaves."

The queen is scenery in the Copse. "The queen stands majectically over all other trees in the area, its leaves reaching out like tendrils holding everything in check."

The bishop is scenery in the Copse. "It is a medium-sized pine with needles that look like cleric's robes."

The knight is scenery in the Copse. "[if golf club is not handled]With a golf club that reaches out like a lance, it points to the southwest, as if insisting that it is the right direction to travel.[otherwise]With a hand that reaches out, it gestures to the southwest, as if insisting that is the right direction to travel."
Instead of examining the knight for the first time: say "With a branch that reaches out like a lance, it points to the southwest, as if insisting that it is the right direction to travel.[line break]Hm. That lance looks more like a golf club.[line break]"; move golf club to Copse.

The king is scenery in the Copse. "You cannot see the king here. It appears to have been toppled."

A golf club is a thing. "[if golf club is not handled]Jutting out from the knight's hand is a golf club, held like a lance." The description of the golf club is "It appears to be a club for hitting golf balls."

Instead of hitting the golf ball with the golf club:
If the golf club is not carried by the player begin;
say "You're not holding the golf club.";
otherwise;
If the golf ball is carried by the player begin;
say "You cannot swing at the golf ball while holding it";
otherwise;
If player is not in the Tee begin;
say "You hit the ball mightiliy, it bounces off of a couple of trees, and returns to your feet.";
otherwise;
say "You hit the ball through the gap in the trees, and hear a loud crash of falling rock.";
remove ball from play;
remove cairn from play;
move pile of stones to clearing;
end if;
end if;
end if.

Instead of swinging the golf club: say "[if the golf club is not in player]You're not holding the club.[otherwise]You take a few practice swings with the club."

The Clearing is southeast of the Copse. "Filtered light through the leaves gives this area an almost underwater feel as you gaze about. You can see a path leading to the northwest."

A cairn is in the Clearing. It is a supporter. "A stone cairn sits in the middle of the clearing." The description of the cairn is "The cairn is rectangular in shape with a square top. It stands about four feet high and made up of stones of various sizes."
After examining the cairn for the first time: say "You see a white sphere sitting on top of the cairn."; Move the golf ball to the cairn.

A pile of stones is fixed in place. "A pile of stones sits in the middle of the clearing, revealing steps going down." The description of the pile of stones is "Unless you knew it, you could never tell it was once a cairn. Steps lead down from where the middle of the cairn used to be."

A golf ball is a thing. Understand "sphere" as the golf ball. Understand "white sphere" as the golf ball. The description of the golf ball is "It's a small sphere about two inches in diameter with dimples all over the surface."
Report throwing the golf ball: say "As you throw the golf ball, it bounces off of a couple of trees, and then rolls to your feet."

The Tee is southwest of the Copse. "A rectangular grassy area stands before you, with a break in the trees to the east. You can see two blue spheres on either side of the area."

spheres is scenery in the Tee. "They stand pefectly opposite one another on either side of the grassy area." Understand "blue spheres" as the spheres.

Antechamber is down from the Clearing. "This is a small room below the cairn. Light filters down from above and not quite reaching into the corners of the room."

Instead of going down from the Clearing:
If pile of stones is in clearing begin;
say "You descend down the steps into the room below.";
move player to Antechamber;
otherwise;
Say "You can't go that way.";
end if.

Instead of going up from the Antechamber:
say "You ascend the stairs into the light.";
move player to Clearing.

Whisper 7 ends when player is in the Antechamber for the first time.

Carry out skipping ahead during Whisper 7:
say "Skipping scene 7.";
remove cairn from play;
move pile of stones to Clearing;
move golf club to player;
move player to the Antechamber, without printing a room description;
rule succeeds.