An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Part 8 - Recap by Lucian Smith

Section 1 - Smith's Part

Whisper 8 is a scene. Whisper 8 begins when Whisper 7 ends.

After looking when in the antechamber, say "An archway in the rocks beckons southeast."

An archway is scenery in the antechamber. Instead of entering the archway, try going southeast.

A tracked room is a kind of a room. Definition: a room is off the tracks if it is not a tracked room.

Instead of going by something to somewhere off the tracks when the location of the player is a tracked room, say "The tracks do not extend in that direction."

The Station Area is a region. The Copse, the Clearing, the Tee, and The antechamber is in the station area.

Southeast of the antechamber is a tracked room called the Great Underground Train Station #7. It is in the station area. "A spacious cavern opens before you, with a ten-glomit wide set of train tracks stretching out to the east and the west."

Some train tracks are scenery in the train station. The description is "Ten glomits wide. You've been told that this is the exact width of six Ancient Remian battle-grues, but given the fact that the Ancient Remian grue-training progam is widely believed to be the cause of the fall of Ancient Reme two weeks after it began, this seems apocryphal."

A push-cart is a rideable vehicle in the train station. "A push-cart sits here on the tracks[if a random chance of 1 in 3 succeeds]. The weasel darts around the handles, curious[end if]." The description is "It looks like you could get in the cart and then simply go along the tracks." Understand "pushcart", "push" and "cart" as push-cart.

A handle is part of the push-cart. The description is "The handle sticks up out of the middle of the push-cart. By moving it up and down, the user can go anywhere on the tracks." Instead of doing anything except examining the handle, say "[bracket]To move the push-cart, just stand on it and type the direction you want to go[close bracket][paragraph break]".

After mounting the push-cart: If the weasel is following begin; now the weasel is in the push-cart; say "The weasel darts between your legs as you step aboard the push-cart, then chirrups and bounces up and down on the handle, ready to go."; end if.

Instead of going from a tracked room to a tracked room when the player is not on the push-cart, say "There's a perfectly good push-cart around here somewhere."

Instead of going west in the train station when the player is not on the push-cart, say "On closer examination, the tracks seem to go straight into the solid rock."

Instead of going inside in the presence of the push-cart, try mounting the push-cart.

Instead of going west in the train station when the player is on the push-cart: move the player to the location, without printing a room description; say "WHAM! You get knocked off the push-cart as it slams into the painted-black west wall. Ha ha, very funny."

After going to a tracked room: if the player is on the push-cart begin; say "You grab a handle and start working it up and down[if the weasel is following], much to the delight of the weasel, who clings with terror and delight to the opposite handle[end if]."; end if; continue the action.

East of the train station is a tracked room called the GUE-Toll. The printed name of the GUE-toll is "Great Underground Toll Booth #568". It is in the station area. "A narrow tunnel of rock surrounds you, dimly lit by glowing moss. The track continues east-west."

Some glowing moss is scenery in the GUE-toll. The description is "Mmm, phosphorescence." Instead of taking the moss, say "Some of the moss comes off onto your fingers, making them glow briefly before it crumbles away."

A toll booth is fixed in place in the GUE-toll. It can be pointing up. It is not pointing up. "Built into the side of the tunnel is a toll booth. The gate beside it is [if pointing up]up, allowing access east[otherwise]down, blocking further passage east[end if]. A slot sits in the middle of the booth." The description is "The toll booth is built into the side of the tunnel. The salient features are a slot (at shoulder height next to you) and a gate[if pointing up], which has swung upwards[otherwise] pointing over the tracks, blocking your cart from further movement[end if]."

Instead of going east in the GUE-toll: If the booth is pointing up begin;
say "The bell clangs as you pass under the gate.";
continue the action;
Otherwise;
say "The gate blocks your way east.";
end if;

Instead of dismounting in the GUE-toll, say "There's not enough room here to get off of the push-cart."

Sufficiency relates one thing to one thing.
The verb to be sufficient for implies the sufficiency relation.

A toll slot is part of the toll booth. It is fixed in place, a container, open, and not openable.

When Whisper 8 begins:
Move the ball to the antechamber;
If at least one thing is held begin;
let payment be a random thing that is held;
otherwise;
let payment be the ball;
end if;
Now the payment is sufficient for the toll slot.

The description is "Above the slot is a picture of [a random thing that is sufficient for the toll slot]."

Instead of inserting something into the toll slot: if the noun is sufficient for the toll slot begin;
Now the booth is pointing up;
Remove the noun from play;
Say "With a clunk, [the noun] disappears into the slot. As it does, the gate swings upwards and a hidden bell rings once.";
rule succeeds;
Otherwise;
Now the noun is in the push-cart;
say "[The noun] disappears into the slot, and you hear a rattling. After a moment, with a rude *blaap*, [the noun] is ejected from the slot and lands with a clunk on the push-cart.";
rule fails;
end if.

A toll gate is part of the toll booth. The description is "[if the booth is pointing up]The gate stands upright, allowing passage further east[otherwise]The gate is down, blocking your cart from moving further east[end if]."

East of GUE-toll is a tracked room called Way Station. It is in the station area . "The tunnel widens here enough to allow room for a small platform. The track from the west splits here, continuing east and southeast."

The platform is scenery in the way station. The description is "Not much more than a few planks fitted together."

Instead of entering the platform, try dismounting.

A large lever is in the way station. It is a fixed in place device. It is switched on. "Mounted to the wall is a large lever, [if switched on]pointed up[otherwise]pointed down[end if]." The description is "The large lever is mounted in the rock, just above the platform by the tracks. It looks extremely corroded and rusty. It points [if switched on]up towards the ceiling[otherwise]down towards the tracks[end if]." Instead of turning or pulling or pushing or switching on or switching off the lever, say "Try as you might, the lever won't budge." Carry out examining the large lever: say "[description]"; stop the action;

The switch tracks are scenery in the way station. The description is "Tracks run east-west here, with a spur heading off to the southeast. It looks like the track can be switched from the east track to the spur, but there's no obvious way to do so. The tracks currently head [if the large lever is switched on]east[otherwise]southeast[end if]."

Instead of turning or pulling or switching on or switching off the switch tracks, say "You know, there's something else around here that might do the trick."

Instead of going east in the way station when the player is not on the push-cart, say "Upon closer examination, those tracks seem to travel directly into solid rock."

Instead of going east in the way station when the player is on the push-cart: if the large lever is switched on begin; move the player to the location, without printing a room description; say "WHAM! You get knocked off the push-cart as it slams into the painted-black east wall. Ha ha, very funny."; otherwise; say "The tracks don't currently go that direction."; end if;

Instead of going southeast in the way station when the player is on the push-cart: if the large lever is switched on begin;
say "The tracks don't currently go that direction.";
stop the action;
otherwise;
continue the action;
end if;

A small shelf is in the way station. It is fixed in place and a supporter.

On the small shelf is a miniature lever. It is a device and switched on. Understand "small", "mini" and "minature" as the miniature lever. The description of the miniature lever is "The miniature lever is an exact replica of the large lever, except that it's not mounted on anything."

Instead of turning or pulling or pushing or switching on or switching off the miniature lever, say "*ZZZT* Yeouch! Your finger gets zapped as you try to manipulate the miniature lever[if the player can see the large lever]. Just as it happened, you saw the large lever wiggle a bit, which is more than you got it to do directly[end if]."

Destining relates one room to one thing.
The verb to be the destiny of implies the destining relation.

A glowing portal is in the way station. "Half of the north wall is taken up with a huge wall of glowing light." Understand "huge", "wall", "glowing", "light", "wall of glowing light", and "wall of light" as the glowing portal. The description is "You peer carefully into the light. It looks vaguely familiar... [The random room that is the destiny of the portal], maybe?"

A light button is a thing. "A small button of light, the same color as the glowing portal, lies here at your feet." Understand "small" and "button of light" as the light button. The description is "It glows invitingly."

Instead of taking or touching or pushing the light button:
say "As you touch the button, you are suddenly sucked inside[if the weasel is following]! Delightedly, the weasel pounces on the button as you disappear.[otherwise]!";
Now the player is in the way station;
if the weasel is following, now the weasel is in the way station;

Instead of entering or touching or climbing the glowing portal:
say "Boldly, you stride towards the wall of light[if the weasel is following]. It would be a bit more dramatic if the weasel didn't bound in front of you and disappear first[end if]."; Let where-to be a random room that is the destiny of the portal;
If the weasel is following, now the weasel is in the where-to;
Now the light button is in the where-to;
Now the player is in the where-to;
stop the action;

Instead of going north in the way station, try entering the glowing portal.

Flippering relates one thing to one device.
The verb to be the flipper of implies the flippering relation.

A thing can be available. A thing is usually not available.

When Whisper 8 begins:
[First, let's try to choose a random person from someone else's section:]
Let proxy be the queen;
Repeat with seen-before running through people begin;
if the location of the seen-before is a visited room, now the seen-before is available;
end repeat;
Now the player is not available; now the weasel is not available;
If the number of available people is at least one begin;
let proxy be a random available person;
otherwise;
[We'll have to make do with an inanimate object]
Repeat with seen-before running through things begin;
If the location of the seen-before is a visited room that is not in the station area, now the seen-before is available;
end repeat;
Now the player is not available; now the weasel is not available;
If the number of available things is at least one begin;
let proxy be a random available thing that is not scenery;
Now the proxy is an Inform library animate object;
end if;
end if;
If the proxy is the queen, now the queen is an Inform library animate object;
Now the proxy is the flipper of the miniature lever;
[Now we need to make sure we know where they are:]
let destiny be the location of the proxy;
if the number of visited rooms adjacent to destiny is at least one begin;
let near-destiny be a random visited room adjacent to destiny;
otherwise;
let near-destiny be destiny;
end if;
Now the near-destiny is the destiny of the glowing portal.
.

The description of the small shelf is "[if the number of things on the shelf is at least one]On the shelf you can see [list of things on the small shelf]. [end if]It looks like someone's drawn a picture of [a random thing that is the flipper of the miniature lever] in the dust on the shelf."

Instead of giving or showing the miniature lever to someone:
if the second noun is the flipper of the miniature lever begin;
if the miniature lever is switched on begin;
Now the miniature lever is switched off;
Now the large lever is switched off;
Say "[The second noun] looks over [the noun] with interest, before casually flipping it, and handing it back to you.";
otherwise;
Say "[The second noun] is no longer interested in [the noun].";
end if;
otherwise;
let pronoun be "he";
if the second noun is not male, let pronoun be "it";
if the second noun is female, let pronoun be "she";
Say "[The second noun] peers at [the noun] curiously, but as [pronoun] reaches out to touch it, [pronoun] seems to sense danger, looks at you sharply, and pulls back.";
end if;

Instead of putting the miniature lever on an inform library animate object thing that is not a person, try showing the miniature lever to the second noun.

Instead of giving or showing the miniature lever to an inform library animate object thing that is not a person:
if the second noun is the flipper of the miniature lever begin;
if the miniature lever is switched on begin;
Now the miniature lever is switched off;
Now the large lever is switched off;
Say "Feeling foolish, you offer the lever to [the second noun]. Astonishingly, it reaches towards you and casually flips the lever. As it straightens back up again, you could swear you see it smile.";
otherwise;
Say "[The second noun] remains impassive.";
end if;
end if;

After examining an inform library animate object thing that is not a person, say "[The noun] looks a bit more sprightly than it did the first time you saw it."

Southeast of the way station is a tracked room called Great Underground Depot.
[The description of the depot is "You can describe this room yourself with a sentence like this. The tracks lead northwest. If you want to continue the tracks, make the room a 'tracked room'"]

Whisper 8 ends when the push-cart is in the great underground depot for the first time.

Carry out skipping ahead during Whisper 8:
say "Skipping scene 8.";
now the push-cart is in the great underground depot;
now the weasel is in the push-cart;
now the player is in the push-cart;
now the large lever is switched off;
now the miniature lever is switched off;
now the miniature lever is carried by the player;
now the light button is in a random room that is the destiny of the glowing portal;
rule succeeds.