An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Part 13 - Archaeology by John Cater

Section 1 - Cater's part

Whisper 13 is a scene. Whisper 13 begins when Whisper 12 ends.

When Whisper 13 begins: say "Time to find your way out of this madhouse."

The Dusty Street is above the Blank Room. "A long dusty street, which runs along the bottom of a deep canyon. The face of the canyon on both sides has been carved into the facades of buildings, although most have been blocked up with rubble. One door to the north seems recently disturbed."

The rickety ladder is fixed in place in the Blank Room. The description of the rickety ladder is "An old rickety ladder in the corner leads up to a hole in the ceiling."

Instead of climbing the rickety ladder, try going up.

After going up from the Blank Room:
say "As you climb the ladder, it starts to shake and shudder. You reach the top and step off just as it falls apart.";
continue the action.

The hole is scenery in the Dusty Street. The description of the hole is "You peer back down into the Blank Room. You can see the pile of wood that used to be a ladder there." Understand "ladder" as the hole.
Instead of going down from the Dusty Street, try examining the hole.

The street rubble is north of the Dusty Street and south of the Stone House. The street rubble is scenery. The street rubble is a closed door. The street rubble is not openable. The description of the street rubble is "[if closed]Rubble fills the doorway, except for a tiny space at the top. It looks as if it settled recently during the explosion[otherwise]RUBBLE OPEN DESC[end if]." Understand "tiny", "space", "door" and "doorway" as the street rubble.

Understand "dig in [something]" as digging.

Instead of digging the street rubble, say "The rubble is too firmly packed out here. It seems like it might be looser inside, but you can't reach that far."

Check inserting something held by the player into the street rubble: Now the noun is in the stone house; say "You push [the noun] into the tiny space, where it disappears. Sadly, the rubble remains impassive."; stop the action.

[Instead of going north from the Dusty Street when the rubble is closed, say "You poke and prod at the rubble filling the doorway, but it won't budge."]

Instead of going through the closed street rubble, say "You squeeze and squeeze, but can't quite fit."

Instead of someone large-size trying going through the closed street rubble, say "[The person asked] tries to squeeze in, but the rubble is in the way."

Instead of someone small-size trying going through the closed street rubble:
say "[The person asked] slides through a small hole you couldn't even fit an arm through.";
now the person asked is in the other side of the street rubble;
rule succeeds.

After going through the open street rubble:
say "You squeeze and squeeze, and just barely fit through.";
continue the action.

The Canyon Wall is east of the Dusty Street. "The street eventually leads you to the smooth wall of the canyon. Even if you had equipment, you'd never manage to climb it."

Some weeds are in the Canyon Wall. "Some weeds grow next to the base of the wall." The description of the weeds is "Small grasslike plants are all that grows in this desert."

The Rockslide is west of the Dusty Street. "A rockslide from the canyon wall blocks the street and any further progress."

A person can be large-size or small-size. A person is usually large-size.

A tamable animal is a kind of animal. A tamable animal can be tame or not tame. A tamable animal is usually not tame.

After going from a room when the room contains a tame tamable animal (called the pet):
try looking;
let goway be the best route from the location of the pet to the location of the player, using doors;
if goway is a direction, try the pet trying going goway.

Persuasion rule for asking a tame tamable animal to try going: rule succeeds.
Persuasion rule for asking a tame tamable animal to try taking: rule succeeds.
Persuasion rule for asking a tame tamable animal to try dropping: rule succeeds.
Persuasion rule for asking a tame tamable animal to try entering something: rule succeeds.
Persuasion rule for asking a tame tamable animal to try exiting: rule succeeds.
Persuasion rule for asking a tame tamable animal to try giving something to the player: rule succeeds.

The mouse is a tamable animal in the Rockslide. The mouse is transparent. The description of the mouse is "[if tame]The mouse sits there, just looking at you[otherwise]You only catch a glimpse of brown fur and a long tail as the mouse scampers away[end if]." The mouse is small-size.

Persuasion rule for asking the mouse to try doing something when the mouse is not tame:
say "As soon as you speak, the mouse burrows deeper into his hiding spot.";
rule fails.

After going when the location of the player is the location of the mouse and the mouse is not tame:
say "As you approach, you see a mouse run and hide under a rock.";
continue the action.

Instead of giving something to the mouse when the mouse is tame:
say "You give [the noun] to the mouse.";
now the mouse has the noun.

Instead of giving something to the mouse when the mouse is not tame:
say "The mouse backs away from you, so you set [the noun] on the ground instead.";
try silently dropping the weeds.

Every turn when the mouse is not tame and the weeds are in the location of the mouse:
say "The mouse carefully crawls over and eats the weeds, and then sits up and stares at you.";
remove the weeds from play;
now the mouse is tame.

Every turn when the mouse is in the Stone House and the street rubble is closed:
say "You hear a small squeak, and then several rocks roll down to you. You think you could squeeze through the rubble now.";
now the street rubble is open.

The description of the Stone House is "The main entry hall of this house is large and echoing. A thick layer of dust covers everything. A door leads to the east, and stairs in the back lead up into darkness."

The dust is scenery in the Stone House. The description of the dust is "A thick layer of dust coats everything you see."

The Kitchen is east of the Stone House. "This was once the kitchen of a great house. Sadly, most of the room is blocked by a rockfall."

The rockfall is scenery in the Kitchen. The description of the rockfall is "It looks like the ceiling collapsed quite a while ago. The rocks look pretty stable now, though."

The drain is an enterable fixed in place container in the Kitchen. "There is an old drain in the middle of the floor." The description of the drain is "A rusty grate covers the drain in the middle of the floor. You see [list of things in the drain] inside the drain." Understand "rusty", "grate", and "cover" as the drain.

A rule for reaching inside the drain:
if the person reaching is the player begin;
say "The grating won't come off, and your hand doesn't fit.";
end if;
if the person reaching is the mouse, try the mouse trying entering the drain instead;
deny access.

Instead of entering the drain, say "That's far too small for you!"
Instead of opening or turning or pushing or pulling or taking the drain, say "It's rusted in place."

Instead of a large-size person trying entering the drain, say "[The person asked] looks at the drain, and shakes his head."

The torch is in the drain. The description of the torch is "A simple wooden torch."

Instead of burning or switching on the torch:
now the torch is lit;
say "The torch blazes into life, throwing shadows around the room."

The Dormitory is a dark room. The Dormitory is above the Stone House. "Stone shelves in the wall are covered in the rotting remains of blankets. A stairway down leads to the Stone House. There is a door to the north."

The rotted blankets are scenery in the Dormitory. The description of the rotted blankets is "These were once light summer blankets, it looks like, before the insects and other vermin had them for lunch."

The metal door is north of the Dormitory and south of the Open Desert. The metal door is a closed openable door. The metal door is scenery. The description of the metal door is "A solid metal door, it looks very sturdy. On this side you see many fanciful inscriptions, most of which appear to be a plea to keep the nomads of the desert away from the inhabitants."

The Open Desert is a room. "The stairs come up into a wild, windswept desert, with sand and gravel going from one horizon to the edge of the canyon."

Whisper 13 ends when the player is in the Open Desert.
When Whisper 13 ends:
say "As you step into the desert, you hear a far-away yipping and yowling, and then ..."

Carry out skipping ahead during Whisper 13:
say "Skipping scene 13.";
move the player to Open Desert;
move the mouse to Open Desert;
now the mouse is tame;
[ if anything special happens during your scene that might need to carry over to the following scene, like a door being unlocked or important objects appearing or disappearing, you can put them here, to make it easier to skip your scene for later debugging ]
rule succeeds.