An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Part 9 - GUDepot by Ricardo Dague

Section 1 - Dague's Part

Whisper 9 is a scene. Whisper 9 begins when Whisper 8 ends.

When Whisper 9 begins:
now the miniature is switched on;
now the gnome man is the flipper of the miniature.

Instead of telling someone about something during whisper 9, try asking the noun about it. Instead of answering someone that something during whisper 9, try asking the noun about it.

A person has a table-name called the replies. The replies of a person is usually Table of Non Replies.

Table of Non Replies
topic   reply
--   "** error: replying to null topic **"

Instead of asking a person about a topic listed in the replies of the noun:
say "[reply entry][paragraph break]".

A heavy item is a kind of thing. After taking a heavy item: say "With great effort you pick up [the noun]." instead.

Before taking a heavy item: if the player carries something, say "You'll have to drop what you're holding. [The noun] is too big to carry along with anything else." instead. Before taking something when a heavy item is carried: let x be a random heavy item which is carried; say "You can't hold anything else along with [the x]." instead. Before removing something from when a heavy item is carried, try taking the noun instead.

Every turn when a heavy item had been carried for 2 turns and one is one: [BUG: the rule doesn't work without this last]
let x be a random heavy item which is carried;
if x is a heavy item begin;
try silently dropping x;
say "You just can't hold [the x] any longer and set it down.";
end if.

A procedural rule: if the push-cart is the second noun, ignore the can't insert into what's not a container rule.

Whisper 9 ends when the push-cart is in the Great Underground Desert for the first time.
[ When Whisper 9 ends: ... ]

Carry out skipping ahead during Whisper 9:
say "Skipping scene 9.";
now push-cart is in great underground desert;
now weasel is in push-cart;
now player is in push-cart;
now miniature lever is switched off;
now miniature lever is carried;
now pink polyester suit is worn;
now gnome man is awake;
now gnome man carries newspaper;
now generator is in Inside Utility Shed;
now generator is switched on;
now power cord is switched on;
now depot is cart east;
remove candy bar from play;
rule succeeds.