An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Section 4 - By the elevator

Elevator Access is a room. "An elevator can be accessed here, at least by someone who isn't worried about being caught. A corridor leads away north. There are doors to the west and south[if lab door is closed and service door is closed], both closed[otherwise if lab door is open and service door is closed]; the former is open[otherwise if lab door is closed and service door is open]; the latter is open[otherwise], both open[end if]." Instead of going nowhere from Elevator Access, say "The corridor leads north; the elevator is east, and there are doors west and south."

A puddle of liquid is a fixed in place thing. It is here. "A puddle of liquid spreads outward from the door to the south." The description is "The puddle of clear liquid is only a few feet wide." Instead of taking the puddle of liquid, say "That's not something you can take." Instead of tasting the puddle of liquid, say "Tasteless." Instead of smelling the puddle of liquid, say "Odorless." Instead of drinking the puddle of liquid, say "Stay on target, Luke." Understand "water" as the puddle.

Instead of inserting the puddle of liquid into the test tube:
if the thimbleful of liquid is not in the test tube begin;
say "You drag the test tube through the puddle, gathering a little liquid.";
move thimbleful of liquid to test tube;
rule succeeds;
otherwise;
say "The test tube is already full.";
end if.

Instead of filling the test tube in the presence of the puddle of liquid, try filling the test tube with the puddle of liquid.

A thing can be reactive.

A thimbleful of liquid is a thing. The description is "A thimbleful of [if reactive]red liquid[otherwise]clear liquid[end if] lies at the bottom of the test tube[if crystal is in the test tube], bubbling around the crystal[end if]." The printed name is "thimbleful of [if reactive]red [end if]liquid".

Instead of doing something other than pouring, pouxing, or examining with the thimbleful, say "You shouldn't handle that directly."

Table of Reaction Messages
reaction
"The crystal reacts vigorously with the liquid, bubbling furiously"
"The crystal continues to react with the liquid, bubbling slowly"
"The crystal shrinks inside as it reacts with the liquid, which is turning red"
"The crystal dissolves away entirely within the liquid"

Reaction turn count is a number that varies.

Every turn when the thimbleful is in the test tube and the crystal is in the tube:
change reaction turn count to reaction turn count plus one;
if reaction turn count <= the number of rows in Table of Reaction Messages begin;
if the test tube is visible begin;
choose row reaction turn count in Table of Reaction Messages;
say "[reaction entry].";
end if;
end if;
if reaction turn count is the number of rows in Table of Reaction Messages begin;
remove crystal from play;
now thimbleful of liquid is reactive;
end if;

A scenery thing called the elevator components is here. The description is "There is a closed elevator door. Above it is a sequence of numbers. Beside the elevator are two buttons, one with an up arrow and one with a down arrow." Understand "call button" and "button" and "up" and "down" and "numbers" and "number" and "circle" and "door" as the elevator components. Instead of doing something other than examining with the elevator components, say "Better to not call any attention to your activities."

Service Access is a room. A service door is south of Elevator Access and west of Closet. It is a door and scenery. The service door is locked.