An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Section 3 - In the lab

Every turn when in the Former Lab for the first turn:
if we have not examined the exterior window,
say "Seems Maurice's insider [italic type]was[roman type] for real."

Former Lab is a room. "You can't say for sure what use this chemistry laboratory may have had before the equipment in it was wrecked, but given why you're here, you've got plenty of suspicions. A path through the mess on the floor has been cleared from the window to the west to the [if lab door is closed]closed [end if]door to the east."

An froomble window is an enterable scenery thing in Former Lab. It has printed name "exterior window". It has the description "Lets in more than just light and fresh air, eh?" Instead of entering the closed froomble window, say "The window is closed." Instead of entering the froomble window, say "The fall would break your neck." Understand "exterior" as the froomble window. Instead of going west in the Former Lab, try entering the froomble window.

A scenery thing called the wrecked equipment is here. It has the description "Various laboratory equipment has been smashed and strewn about throughout the room. Trashed test tubes, bashed beakers, demolished dessicators, munged microscopes; it's all here, scattered about the floor and the countertops. Cabinet doors lie open, their contents removed or destroyed." Understand "trashed" and "test" and "tube" and "tubes" and "bashed" and "beaker" and "demolished" and "dessicator" and "munged" and "microscope" and "laboratory" and "mess" and "detritus" and "cabinets" as the wrecked equipment.

Instead of searching the wrecked equipment:
if the noun does not hide anything begin;
say "You search the detritus carefully, but can find nothing of further interest.";
otherwise;
let the discovery be a random thing hidden by the noun;
now the discovery is carried by the player;
now the noun hides 0;
say "Searching through the detritus in the room, you eventually discovered an intact [discovery]. You lift it free.";
end if.

A thing can be oversized or test-tube-sized. The crystal is test-tube-sized.

A test tube is a container hidden by the wrecked equipment. The description is "Clear, unblemished glass shaped into a tube wide enough to contain a nut." Instead of inserting something oversized into the test tube, say "That won't fit."

Report examining the test tube when the test tube contains something:
say "In [the noun] [is-are list of things in the noun]."

To stick (X - thing) in (Y - thing):
if Y is a container, try silently inserting X into Y;
if Y is a supporter, try silently putting X on Y;
if X is not in Y and X is not on Y,
move X to location.

A tiny puddle is a thing. The description is "A tiny puddle of [if reactive]red [end if]liquid." The printed name is "tiny puddle of liquid".

At the time when puddle dissipates:
if player can see puddle, say "The tiny puddle of [if puddle is reactive]red [end if]liquid seeps away.";
remove puddle from play.

To puddleify (X - object):
move tiny puddle to X;
now tiny puddle is not reactive;
if thimbleful is reactive, now tiny puddle is reactive;
remove thimbleful from play;
now thimbleful is not reactive;
puddle dissipates in two turns from now.

Instead of pouring the test tube on something (called target):
if the test tube contains something begin;
say "You pour [the list of things in the noun] on [the target].";
if thimbleful is in test tube and target is not a container, puddleify location;
if crystal is in test tube begin;
stick crystal in target;
end if;
otherwise;
say "There's nothing in the test tube.";
end if.

Instead of pouxing the test tube:
if the test tube contains something begin;
say "You pour [the list of things in the noun] on the ground.";
if thimbleful is in test tube, puddleify location;
if crystal is in test tube begin;
move crystal to location;
end if;
otherwise;
say "There's nothing in the test tube.";
end if.

Instead of pouring something in the test tube on something (called target), try pouring the test tube on the target.

Instead of pouxing something in the test tube, try pouxing the test tube.

Instead of filling the test tube in the presence of the tiny puddle, try filling the test tube with the tiny puddle.

A lab door is east of Former Lab and west of Elevator Access. It is a door and closed and scenery. Instead of going nowhere from the Former Lab, say "The only exit from the lab is through the door to the east."