An Escape To Remember

An interactive fiction by the IF Whispers Team (2006) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Section 2 - Dangling on the rope

Dangling is a room. The printed name of dangling is "On the rope". "A light breeze rocks you gently back and forth as you dangle near the end of the colored sashes. In front of you is an open window." Instead of selfswinging on the brightly-colored sashes in Dangling, try xselfswinging. Instead of going down from Dangling, say "That'll happen soon enough." Instead of going up from Dangling, say "No turning back now."

Instead of taking the brightly-colored sashes when in Dangling, say "You can do that [italic type]after[roman type] you lift yourself up with your bootstraps."

The exterior window is an open scenery door. It is east of Dangling. Through it is the Former Lab. The description is "Looks like Maurice's insider [italic type]was[roman type] for real."

Instead of climbing the exterior window, try entering the exterior window. Instead of going through the closed exterior window, say "The window is shut."

At the time when the ripple returns:
now the ripple is in the balcony;
if the player is in the balcony, say "A faint shimmer in the air is the only thing that announces the ripple has reformed.";
if the player is in dangling begin;
say "A faint shimmer in the air announces that the ripple has reformed; the sudden reassertion of gravity upon your person confirms it.[line break]That is to say: you are falling.[line break]";
the player falls to her death in zero turns from now;
end if.

At the time when the player falls to her death:
if in dangling begin;
say "The fall breaks your neck.";
end the game in death;
end if.

swinging2 is a number that varies. swinging2 is 0.

Before going through the exterior window when in Dangling:
if swinging2 is 0 begin;
say "The window is just out of reach.";
stop the action;
end if;
say "Swinging on the make-shift rope, you just manage to reach the window and dive through it.[line break]".

Instead of selfswinging through the exterior window when in Dangling:
say "You swing through the window, almost hoping someone will be inside to see your daring maneuver.";
move player to Former Lab.

Instead of selfswinging to the exterior window when in Dangling:
say "[if swinging2 is 1]You swing over to the window.[otherwise]You begin swinging yourself back and
forth, dangling from the sashes, until you swing close to the window.";
change swinging2 to 1.

Instead of xselfswinging when in Dangling:
say "You [if swinging2 is 1]swing[otherwise]begin swinging[end if] yourself back and forth, dangling from the sashes.";
change swinging2 to 1.

Instead of swinging the sashes, try xselfswinging.

Instead of jumping in Dangling, try climbing the exterior window.

After dropping something (called the X) in Dangling:
say "[The X] slips from your hand and falls out of your sight.";
remove the X from play.